項目

図形描画の長さ単位にmmを用いる

内容説明

図形描画の長さ単位はポイント(pt)が用いられています。 長さの関係は 1ｲﾝﾁ=25.4mm=72pt です。
長さをmm単位で指定する場合の変換係数は次のようになります。
kk = 72/25.4 '変換係数=2.834645669
pt = mm * kk '1mm=2.834645669pt

Excelの図形描画での最小単位は0.75ポイント(0.2646mm)です。従ってExcelでは精密な図形描画は出来ません。
mmを0.75ポイントの倍数に変換するMM2PT関数を示します。

'mmを描画単位0.75ptの倍数に変換
Function MM2PT(mm)
  MM2PT = Int(72 / 25.4 * mm / 0.75 + 0.5) * 0.75
End Function

一般的に、指定値の倍数になるよう数値を丸めるMROUND2関数は次のようになります。

'MROUND2(数値, 倍数)
'数値   丸める数値を指定します
'倍数   倍数数値を指定します
Function MROUND2(vv,bb)
  MROUND2 = Int(vv / bb + 0.5) * bb
End Function

追記)長さ変換のメソッド
CentimetersToPoints メソッド
センチメートル単位の数値をポイント(1ポイントは0.35mm)単位に変換します。

InchesToPoints メソッド
インチ単位の数値をポイント単位に変換します｡

項目

ユーザー作成のヘルプファイルを起動する

内容説明

ユーザーが作成したヘルプファイル(拡張子hlp/chm)を起動する方法です。
• コマンドボタンやメニューからヘルプを起動する
  ユーザーフォーム やダイアログファーム等の[ヘルプ]ボタンなら[マクロの登録]で、メニューやツールバーのボタンならOnActionプロパティで、ヘルプを起動する関数を設定します。
  ヘルプを起動する関数は Helpメソッドを使います。
  Helpメソッドの構文
  Application.Help (helpFile, helpContextID)
  helpFile：
  ヘルプファイルの名前を指定します。この引数を省略するとExcelのヘルプ ファイルが使われます。
  helpContextID：
  ヘルプトピックのコンテキストIDを指定します。この引数を省略すると[トピックの検索]ダイアログボックスが表示されます。
  

  '■ヘルプを起動する関数例
  Sub test_Help1() 'Excelフォルダのxxx.hlpのヘルプトピックHelpContextID=2を起動
    Application.Help Application.Path & "\xxx.hlp", 2
  End Sub
  
  Sub test_Help2() 'ThisWorkbookフォルダのxxx.chmを起動
    Application.Help ThisWorkbook.Path & "\xxx.chm"
  End Sub
  

• メニュー(コマンド バーコントロール)にヘルプトピックを関連付ける
  [Shift]キーを押しながら[F1]キーを押し、該当するコマンド バーコントロールを押すとヘルプトピックが表示されます。

  '■ヘルプトピックの設定例
  Sub testHelpTopicAdd()
    testHelpTopicDel
    With Application.CommandBars.Add(Name:="testHelpTopic", Temporary:=True)
      .Visible = True
      With .Controls.Add(Type:=msoControlButton)
        .Caption = "Aaa"
        .FaceId = 266
        .OnAction = "aaa"
        .HelpFile = "c:\ddd\eee\fff.hlp"
        .HelpContextID = 3
      End With
    End With
  End Sub
  Sub testHelpTopicDel()
    On Error Resume Next
    Application.CommandBars("testHelpTopic").Delete
  End Sub
  

• ユーザーフォームにコンテキストヘルプを関連付ける
  ユーザーフォームで[F1]キーを押したときヘルプファイル内のトピックが表示されます。設定手順は以下。

  VBEの[ツール]-[VBAProjectのプロパティ]を開き [ヘルプファイル名] に使用するヘルプを設定
  ユーザーフォームのプロパティで次の2つを設定
  HelpContextID プロパティ　ヘルプトピックのコンテキストID(正の整数値)を指定
  WhatsThisHelp プロパティ　Trueを指定 
  
  '■マクロで[VBAProjectのプロパティ]の[ヘルプファイル名]の設定例
    ThisWorkbook.VBProject.HelpFile = ThisWorkbook.Path & "\xxx.chm"
  注)VBIDEインターフェイスを使用するため[セキュリティ]-[信頼のおけるソース元]のチェックが必要。
  

• ユーザー関数のヘルプを[関数ウィザード]で表示する
  ユーザー関数のヘルプを [関数ウィザード]で表示したり、関数を[ツール]メニューへ登録するには[オブジェクトブラウザ]をつかいます。
  [表示]-[オブジェクトブラウザ]を開き 設定する関数を選択し[オプション]ボタンを押します。
  [マクロオプション]画面で[説明][ヘルプID][ヘルプファイル名]等を入力します。

  '■マクロでMacroOptionsメソッドでの設定例
    Application.MacroOptions Macro:="proc", _
      Description:="arg1:引数1の説明" & vbCrLf & "arg2:引数2の説明", _
      HelpContextID:=1, HelpFile:="c:\ddd\eee\fff.chm"
  

• MsgBoxやInputBoxでHelpを表示する
  MsgBoxやInputBoxの引数helpfile 及びcontext を指定すると、ダイアログ ボックスに自動的に[ヘルプ]ボタンが追加されます。構文を以下に示します。
  

  MsgBox(prompt[,buttons][,title][,helpfile,context])
  InputBox(prompt[,title][,default][,xpos][,ypos][,helpfile,context])
  helpfile ：ヘルプファイルの名前
  context  ：ヘルプトピックに指定するコンテキストID
  

項目

VBA Excel本体を非表示にしてフォームのみ表示する

内容説明

Excelを最小化してフォーム(ダイアログ)のみ表示するサンプルを示します。

Sub test1_E97M038() 'Excelを最小化してユーザーフォームのみ表示するサンプル
  Application.WindowState = xlMinimized 'Excelウィンドウを最小化
  'ウィンドウを最小化すると他にフォーカスが移るのでAppActivateで戻す
  AppActivate Application.Caption 'Excelをアクティブにします
  UserForm1.Show 'ユーザーフォームの表示
  'DialogSheets("Dialog1").Show 'ダイアログの表示
  'Application.WindowState = xlNormal 'Excelウィンドウを元に戻す
End Sub

次ぎの例はVisibleプロパティを用いてオブジェクト(この場合Excel)を非表示にします。
この場合はタスクバーにも表示されないのでユーザーの操作で元に戻す事は出来ません。 Application.Visible = True を実行しない限り表示されませんのでご注意下さい。
フォームでの作業が中心でExcel本体を表示させたくない場合に用いる事が出来ます。

Sub test2_E97M038() 'Excelを非表示にする例
  Application.Visible = False '非表示
  'UserForm1.Show 'ユーザーフォームの表示
  MsgBox "Excelを非表示にしました." & vbCrLf & _
    "タスクバーにも表示されていません." & vbCrLf & _
    "[OK]ボタンをクリックすると元に戻ります."
  Application.Visible = True '表示
End Sub

何よりも先にユーザーフォームを表示する方法
ユ-ザ−フォ−ムのみで作業を行う行うExcelアプリケ−ションの場合に、Excel本体を一切表示せずユーザーフォームを表示する方法です。
ThisWorkbookのSub Workbook_Openに次のように記述します。

Private Sub Workbook_Open()
  Application.Visible = False '非表示
  UserForm1.Show
End Sub

次に、Excelアプリケ−ション(xls,xla)の[ショートカット]を作り、[ショートカット]の[プロパティ]で[実行時の大きさ]を[最小化]に設定しておきます。
[ショートカット]で起動すると、Excel本体は表示されず即ユーザーフォームが立ち上がります。

項目

実行中のマクロを強制終了する

内容説明

実行中のマクロを強制終了するには[Esc]キーを押します。(又は[Ctrl]+[Break]キーでも同様)

[Esc]キーによる強制終了を出来ないようにマクロを記述するにはEnableCancelKeyプロパティにxlDisabledを設定します。
このプロパティは慎重に扱って下さい。無限ループのような自分で停止しないプロシージャを止めることが出来なくなります。
次の1行をプロシージャに記述します。

Application.EnableCancelKey = xlDisabled '強制終了を無視します

[Esc]キーによる強制終了を有効にするには次の様にxlInterruptを設定します。 なお、プロシージャが終了するとEnableCancelKeyプロパティは常にxlInterruptに戻されます。

Application.EnableCancelKey = xlInterrupt

[Esc]キーが押されて強制終了した時に何らかの後処理が必要な場合は、EnableCancelKeyプロパティにxlErrorHandlerを設定しエラートラップを行います。
xlErrorHandlerを設定すると実行中のプロシージャに対してエラー番号18が送られ、On Error GoTo ステートメントでトラップ出来ます。
以下にに使用例を示します。

Sub test_E97043() 'Escキーが押された場合のエラートラップ例
  Dim ii&, jj&
  On Error GoTo HandleErr
  Application.EnableCancelKey = xlErrorHandler
  MsgBox "この処理には時間がかかります。強制終了は[Esc]キーを押してください"
  Application.DisplayStatusBar = True
  For ii = 1 To 1000
    Application.StatusBar = "実行中です。  " & ii & "/1000"
    For jj = 1 To 500000
    '
    Next
  Next
  Application.StatusBar = False
  Exit Sub
HandleErr:
  If Err = 18 Then 'ESCが押された
    MsgBox "強制終了しました"
  Else
    MsgBox "エラー:" & Err & vbCrLf & Error
  End If
  Application.StatusBar = False
End Sub

項目

上のセルと値が同じなら〃と表示する関数

内容説明

表(ｾﾙ)の値が上のセルと同じなら〃と表示したい場合があります。
その機能を実現するkSameOn関数を示します。
この機能はセルの表示方法を替えているだけなのでセルの値は本来のままです。

使い方は、セル範囲を選択しkSameOn関数を実行します。
選択範囲は複数でもOKです。
元に戻すには、[書式]-[ｾﾙ]-[表示形式]を変更します。又、セルの値を変更した場合にも自動的には反映されませんので再度関数を実行します。

'上のセルと値が同じなら〃と表示する関数
'範囲を選択して関数を実行します
'表示形式を変えているだけなのでセル値は変わらない
Sub kSameOn()
  Dim sc As Range
  For Each sc In Selection.Cells
    If sc.NumberFormat = """〃"";""〃"";""〃"";""〃""" Then sc.NumberFormat = "G/標準"
    If sc.Row > 1 And sc <> "" Then
      If sc = sc.Offset(-1, 0) Then
        sc.NumberFormat = """〃"";""〃"";""〃"";""〃"""
      End If
    End If
  Next
End Sub

項目

VBA OnEntry等でプロシージャを指定する際に引数を渡す方法

内容説明

OnEntry等でプロシージャを指定する際に引数を渡したい場合があります。
プロシージャの名前を指定する文字列で、プロシージャ名と引数をシングルクォーテーション(')で囲んで指定します。
文字列の作成は "'プロシージャ名 引数１'" のようになります。引数が文字列の場合は引数をダブルクウォーテーションで囲みます。
以下に、プロシージャを指定する際に引数を渡すサンプルを示します。


'OnEntry等でプロシージャを指定する際に引数を渡す方法
'プロシージャ名と引数をシングル クォーテーションで囲んだ文字列で指定
'文字列の作成  "'プロシージャ名 引数１'"
'引数が文字列の場合は引数をダブルクウォーテーションで囲む
Sub test_E97039()
  Dim aa, bb, prc$
  aa = "abc"
  bb = 123
  'prc = "'prc0 """ & aa & """'" '文字変数の指定
  'prc = "'prc0 " & bb & "'"     '数値変数の指定
  'prc = "'prc0 ""abc""'"        '文字列の指定
  'prc = "'prc0 123'"            '数値の指定
  'prc = "'prc0 ""abc"",123'"    '文字変数と数値変数の指定
  prc = "'prc0 """ & aa & """," & bb & "'" '文字列と数値の指定
  MsgBox prc
  Worksheets(1).OnEntry = prc
End Sub
Sub prc0(aa, Optional bb)
  MsgBox aa
  If Not IsMissing(bb) Then MsgBox bb
End Sub

項目

VBA 省略可能な引数を受け取るプロシージャの記述

内容説明

省略可能な引数を受け取るプロシージャ(Sub,Function)の記述例を示します。
省略可能なパラメータを受け取るにはキーワード Optionalを用います。
プロシージャに省略可能な引数が渡されたかどうかを調べるにはデータ型Variantの場合IsMissing 関数を用います。


'省略可能な引数を受け取るプロシージャの記述例
Sub test1_E97038()
  Dim p1, p2
  a_E97038o "aaa"
  a_E97038o 111, "aaa"
  a_E97038o "aaa", "bbb", 999
End Sub
Sub test2_E97038(aa, Optional o1, Optional o2)
  If IsMissing(o1) Then o1 = 1
  If IsMissing(o2) Then o2 = 1
  MsgBox aa & " " & o1 & " " & o2, , "パラメータ"
End Sub

参照：E95M002任意の数の引数を受け取るプロシージャの記述

項目

VBA制御に関する構文メモ

内容説明

VBAのコ−ド実行の制御に関する構文メモです。

条件により異なるコ−ドを実行する(条件判断構造)
If...Then...Else ステートメントの構文
式の値に基づいて、条件付きの実行を行うフロー制御ステートメントです。
If condition Then [statements][Else elsestatements]
または 次に示すブロック形式の構文を使用することもできます。
If condition Then


[statements]
[ElseIf condition-n Then
[elseifstatements] ...
[Else
[elsestatements]]


End If

Select Case ステートメントの構文
条件式の値に従って、複数のステートメント ブロックのいずれかを実行させるフロー制御ステートメントです。
Select Case testexpression


[Case expressionlist-n
[statements-brn]] ...
[Case Else
[elsestatements]]


End Select

同じコ−ドの反復実行(ル−プ)
Do...Loop ステートメントの構文
指定した条件が真 (True) である間、または条件が真 (True) になるまで、一連のステートメントを繰り返し実行するフロー制御ステートメントです。
Do [{While | Until} condition]


[statements]
[Exit Do]
[statements]


Loop
または 次の構文を使用できます。
Do


[statements]
[Exit Do]
[statements]


Loop [{While | Until} condition]

For...Next ステートメントの構文
指定した回数だけ、一連のステートメントを繰り返すフロー制御ステートメントです。
For counter = start To end [Step step]


[statements]
[Exit For]
[statements]


Next [counter]

For Each...Next ステートメントの構文
配列やコレクションの各要素に対して、一連のステートメントを繰り返し実行するフロー制御ステートメントです。
For Each element In group


[statements]
[Exit For]
[statements]


Next [element]

項目

VBA変数に関する構文メモ

内容説明

VBAの変数に関連する構文のメモです。

Option Explicit '変数の明示的な宣言を強制する
Sub プロシージャの構文
[Private | Public] [Static] Sub name [(arglist)]


[Exit Sub]


End Sub
Function プロシージャの構文
[Public | Private] [Static] Function name [(arglist)] [As type]

[name = expression]
[Exit Function]


End Function
変数の宣言 Dim、Private、Public、ReDim、Static
Dim varname [As type]


Public：すべてのモジュールのすべてのプロシージャから参照できる
Private ：モジュール内でのみ参照できる(省略値)
Static ：プロシージャ内のローカル変数が保持される


変数のデータ型[type]

バイト型(Byte)、ブール型(Boolean)、整数型(Integer)、長整数型(Long)、通貨型(Currency)、単精度浮動小数点数型(Single)、倍精度浮動小数点数型(Double)、10進型(Decimal)、日付型(Date)、文字列型(String)(固定長の場合は String * length)、オブジェクト型(Object)、バリアント型(Variant)(省略値)、ユーザー定義型、オブジェクト型

記号による簡単な変数宣言[type]

varname%：整数型(Integer) varname As Integer と同じ
varname!：単精度浮動小数点数型(Single)
varname#：倍精度浮動小数点数型(Double)
varname$：文字列型(String)


ユーザー定義型の構文
[Private | Public] Type varname


elementname [([subscripts])] As type
...


End Type


配列の構文
Dim aa(100) As Integer 'aa(0)〜aa(99)
Option Base 1 'インデックス番号の最小値の変更
Dim bb(1 To 100) 'To節の使用。bb(1)〜bb(100)のVariant型
Dim cc(10,10) '多元配列。最大60次元
Dim dd As String * 100 '長さ100バイトの文字列変数宣言
TypeName 関数：変数に関する情報を得る
VarType 関数：変数の内部処理形式を調べる
IsNumeric 関数：Variant型変数が数値として扱えるか調べる
IsEmpty 関数：変数がEmpty値かどうかを調べる
Const ステートメント構文。独自の定数の定義
[Public | Private] Const constname [As type] = expression

項目

ダイアログの表示中にワークシートのスクロールや切り替えを行う

内容説明

ユーザーが作成したダイアログフレームを表示して操作を行う場合に、ワークシートをスクロールしてセルの値を参照したい場合があります。
通常はそのような動作は出来ませんが、裏技でスクロールやシート見出しの切り替えが出来るkDlgScroll関数を示します。

ダイアログを表示するShowメソッドに代えてkDlgScroll関数を用いて下さい。
ダイアログでの操作中に、アクセスキー([Alt]+[S]キー)を押すとスクロールが可能となります。ダイアログのコントロールにフォーカスを戻すとスクロール不可となります。
処理過程でダイアログの枠外に [エディットボックス]と[コマンドボックス]を作成し機能を実現しています。
また、[OK]ボタンへ[マクロの登録]をしているので既に他のマクロを登録してある場合は一部修正が必要です。

'ダイアログの表示中にワークシートのスクロールや切り替えを行うkDlgScroll関数
'ダイアログを表示するShowメソッドに代えてkDlgScroll関数を用いて下さい。
'引数 dlg:表示するダイアログ名
'  ac :アクセスキー。省略可、省略値は"S"
'    [Alt]+[S]キーを押すとスクロールが可能となる。
'    コントロールにフォーカスを戻すとスクロール不可となる。
Sub kDlgScroll(dlg, Optional ac$ = "s")
  Dim ds As Object
  Set ds = ThisWorkbook.DialogSheets(dlg)
  On Error Resume Next
  ds.EditBoxes("kDlgS_E").InputType = xlReference
  If Err = 1004 Then
    ds.EditBoxes.Add(ds.DialogFrame.Left, ds.DialogFrame.Top - 15, 50, 13).Name = "kDlgS_E"
    ds.EditBoxes("kDlgS_E").InputType = xlReference: Err = 0
  End If
  ds.DrawingObjects("kDlgS_B").Accelerator = ac
  If Err = 1004 Then
    ds.Buttons.Add(ds.DialogFrame.Left, ds.DialogFrame.Top - 15, 30, 13).Name = "kDlgS_B"
    ds.DrawingObjects("kDlgS_B").Accelerator = ac
    ds.DrawingObjects("kDlgS_B").OnAction = "kDlgScroll1"
  End If
  On Error GoTo 0
  ds.DrawingObjects("ボタン 2").OnAction = "kDlgScroll2" '[OK]ボタンへ[マクロの登録]
  ds.Show
End Sub
Sub kDlgScroll1()
  ActiveDialog.Focus = ActiveDialog.EditBoxes("kDlgS_E").Name
End Sub
Sub kDlgScroll2() 'この関数を[OK]ボタンへ[マクロの登録]
  ActiveDialog.EditBoxes("kDlgS_E").Text = ""
End Sub

'kDlgScroll関数のTEST
'ダイアログの表示中にスクロールを行う
Sub test_kDlgScroll() 
  kDlgScroll "Dialog1"
End Sub